소니 AVCHD 파일 변환기 없이 맥북에서 읽어오기

이미지
 아주예전에 구입했던 소니 HDR-CX12 모델. 생각보다 쓰지 않고 처박혀 있던 녀석을 꺼낸 이유는 꼬맹이가 비디오 촬영에 흥미를 가졌기 때문이다. 다른 컴팩트 카메라를 한대 손에 쥐어 주었는데, 얼마전 찍은 동영상 아빠한테 보여준다고 뛰어오다 떨어트려서 아작이 나버렸다. ㅠㅠ 생각난 김에 처박혀 있던 카메라를 줄려고 꺼내어 보았는데, 특별히 문제 없이 동작중이다. 2008년 모델인데 아무 문제 없이 움직이고 있다. 사스가 소니! 다만 문제는 테스트 용으로 촬영한 동영상을 보려고 메모리 카드에서 파일을 읽어보니 달랑 AVCHD 란 파일 하나만 존재하고 있다. 혹시나 싶어 인터넷에서 매뉴얼을 찾아 읽어보아도, 전용 드라이버를 설치하라고 하는데, 이게 또 귀차니즘이 마구 몰려온다. 같은 avchd 이니 확장자를 m2ts 로 바꾸면 어떨가 싶어 확장자를 바꾸어 보았는데 뜬금 없이 디렉토리로 표시된다.    디렉토리로 되었으니 열어보아야지 하는 마음으로 열어보니 이번엔 BDMV 라는 확장자도 없는 파일이 또 표시되길래 혹시나 싶어 이 파일도 확장자를 m2ts 로 바꾸어 주었다. 확장자를 바꾸어 주니 이 파일도 디렉토리로 표시되었다.   와우, 그랬더니 여러가지 파일과 디렉토리가 표시된다. 이게 바로 처음 메모리 카드를 넣었을때의 비디오 인덱스인 듯 하다. 파일이름에도 인덱스가 들어 있고,디렉토리도 딱 보니 클립, 플레이 리스트, 스트리밍 동영상 등등 어디서 많이 들어본 단어 들이다. 동영상 파일은 예상대로 STREAM 디렉토리 안에 존재하고 있었고 확장자는 MTS 로 맥용 동영상 플레이어인 IINA에서 바로 플레이 할 수 있는 걸 확인했다. IINA에서 다른 동영상 포맷으로 변환은 안되지만 다른 어플을 이용하면 간단하게 처리 할 수 있을 듯 하다. m2ts 가 이런 형식으로 되어 있는 것도 오늘 처음 알았다. 나중을 위하여 메모 겸 남겨 놓는다.  

Windows의 제품키 표시해주는 Script

 가끔씩 윈도우즈의 제품키를 확인할 필요가 있다.

특히나 회사에서 PC들을 관리할때 이 PC가 대체 어떤 제품키를 이용하고 있는 중인지 파악이 안될때 매번 레지스트리 편집기를 열어서 확인하는게 귀찮은 작업이었다. 구글링으로 검색하여 보니 아니나 다를까 같은 고민을 하는 수많은 유저들에 의해서 이미 많은 vbs스크립트가 제작되어 있었기에 그중에 아무거나 하나 골라 백업용도로 저장해 놓도록 한다.

Windows7이하의 경우

Set WshShell = WScript.CreateObject("WScript.Shell")
 
KeyPath = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\DigitalProductId"
MsgBox ExtractKey(WshShell.RegRead(KeyPath))
 
Function ExtractKey(KeyInput)
    Const KeyOffset = 52
    i = 28
    CharWhitelist = "BCDFGHJKMPQRTVWXY2346789"
    Do
        Cur = 0
        x = 14
        Do
            Cur = Cur * 256
            Cur = KeyInput(x + KeyOffset) + Cur
            KeyInput(x + KeyOffset) = (Cur \ 24) And 255
            Cur = Cur Mod 24
            x = x -1
        Loop While x >= 0
        i = i -1
        KeyOutput = Mid(CharWhitelist, Cur + 1, 1) & KeyOutput
        If (((29 - i) Mod 6) = 0) And (i <> -1) Then
            i = i -1
            KeyOutput = "-" & KeyOutput
        End If
    Loop While i >= 0
    ExtractKey = KeyOutput
End Function
 

Windows8이상의 경우

Option Explicit
 
Dim objshell,path,DigitalID, Result
Set objshell = CreateObject("WScript.Shell")
'Set registry key path
Path = "HKLM\SOFTWARE\Microsoft\Windows NT\CurrentVersion\"
'Registry key value
DigitalID = objshell.RegRead(Path & "DigitalProductId")
Dim ProductName,ProductID,ProductKey,ProductData
'Get ProductName, ProductID, ProductKey
ProductName = "Product Name: " & objshell.RegRead(Path & "ProductName")
ProductID = "Product ID: " & objshell.RegRead(Path & "ProductID")
ProductKey = "Installed Key: " & ConvertToKey(DigitalID)
ProductData = ProductName  & vbNewLine & ProductID  & vbNewLine & ProductKey
'Show messbox if save to a file
If vbYes = MsgBox(ProductData  & vblf & vblf & "Save to a file?", vbYesNo + vbQuestion, "BackUp Windows Key Information") then
   Save ProductData
End If
 
'Convert binary to chars
Function ConvertToKey(Key)
    Const KeyOffset = 52
    Dim isWin8, Maps, i, j, Current, KeyOutput, Last, keypart1, insert
    'Check if OS is Windows 8
    isWin8 = (Key(66) \ 6) And 1
    Key(66) = (Key(66) And &HF7) Or ((isWin8 And 2) * 4)
    i = 24
    Maps = "BCDFGHJKMPQRTVWXY2346789"
    Do
       Current= 0
        j = 14
        Do
           Current = Current* 256
           Current = Key(j + KeyOffset) + Current
           Key(j + KeyOffset) = (Current \ 24)
           Current=Current Mod 24
            j = j -1
        Loop While j >= 0
        i = i -1
        KeyOutput = Mid(Maps,Current+ 1, 1) & KeyOutput
        Last = Current
    Loop While i >= 0
    keypart1 = Mid(KeyOutput, 2, Last)
    insert = "N"
    KeyOutput = Replace(KeyOutput, keypart1, keypart1 & insert, 2, 1, 0)
    If Last = 0 Then KeyOutput = insert & KeyOutput
    ConvertToKey = Mid(KeyOutput, 1, 5) & "-" & Mid(KeyOutput, 6, 5) & "-" & Mid(KeyOutput, 11, 5) & "-" & Mid(KeyOutput, 16, 5) & "-" & Mid(KeyOutput, 21, 5)
  
   
End Function
'Save data to a file
Function Save(Data)
    Dim fso, fName, txt,objshell,UserName
    Set objshell = CreateObject("wscript.shell")
    'Get current user name
    UserName = objshell.ExpandEnvironmentStrings("%UserName%")
    'Create a text file on desktop
    fName = "C:\Users\" & UserName & "\Desktop\WindowsKeyInfo.txt"
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set txt = fso.CreateTextFile(fName)
    txt.Writeline Data
    txt.Close
End Function

 각 파일을 확장자 vbs로 저장하여 실행

 

댓글

이 블로그의 인기 게시물

소니 AVCHD 파일 변환기 없이 맥북에서 읽어오기

해외거주 국민을 위한 "교민폰" 사용후기

CISCO 2960s 초기화 후 기본 설정